Radial Wavefunctions

SetOptions[Plot,PlotStyle->Thick,ImageSize->450,PlotRange->All,AxesOrigin->{0,0}];
SetOptions[Manipulate,BaseStyle->{FontSize->20}];
SetOptions[Manipulator,Appearance->"Labeled"];
TwoAxisPlot[{f_,g_},{x_,x1_,x2_}]:=Module[{fgraph,ggraph,frange,grange,fticks,gticks},{fgraph,ggraph}=MapIndexed[Plot[#,{x,x1,x2},Axes->True,PlotStyle->ColorData[1][#2[[1]]]]&,{f,g}];{frange,grange}=(PlotRange/.AbsoluteOptions[#,PlotRange])[[2]]&/@{fgraph,ggraph};fticks=N@FindDivisions[frange,5];
gticks=Quiet@Transpose@{fticks,ToString[NumberForm[#,2],StandardForm]&/@Rescale[fticks,frange,grange]};
Show[fgraph,ggraph/.Graphics[graph_,s___]:>Graphics[GeometricTransformation[graph,RescalingTransform[{{0,1},grange},{{0,1},frange}]],s],Axes->False,Frame->True,FrameStyle->{ColorData[1]/@{1,2},{Automatic,Automatic}},FrameTicks->{{fticks,gticks},{Automatic,None}}]]

In this worksheet, you will explore the graphs of the radial wavefunctions, ((Subscript[R, n])^l)(r)’s, in terms of the orbital quantum numbers n and l.

We will start by setting both Zq, the charge on the nucleus, and a0, the Bohr radius, to 1:

Zq=1;
a0=1;

Before we calculate the radial wavefunction, let's see what the Laguerre factor looks like. To do this, first we define the Laguerre polynomials (Laguerre), (Subscript[L, n])(x), and the associated Laguerre polynomials (ALaguerre), ((Subscript[L, n])^l)(x).

Manipulate[
ALaguerreLabel=StringForm["((Subscript[L, ``])^(``))(ρ)=",n,l][Simplify[LaguerreL[n,l,ρ]]];
ALaguerrePlot=Plot[Simplify[LaguerreL[n,l,ρ]],{ρ,-2*n,4*n},PlotRange->{-3n^2(l+1)^2,3n^2(l+1)^2}];
Grid[{{ALaguerreLabel},{},{ALaguerrePlot}},Alignment->Left],
{n,1,10,1},{l,0,n-1,1},TrackedSymbols:>{n,l}]

1) Describe how associated Laguerre polynomials depend on n and l.

This is written with the variable ρ, which is the dimensionless parameter we used in class. The following code replaces every ocurrence of ρ in LaguerreL[n-l-1,2l+1,ρ] with ((2Zq r)/(n a0)).

Lr[n_,l_]:=LaguerreL[n-l-1,2l+1,ρ]/.{ρ->2Zq r/(n a0)}

2) Why must we replace ρ with ((2Zq r)/(n a0)) in the Laguerre polynomial?

The radial wavefunction’s normalization is given by:

Nom[n_,l_]:=-(Sqrt[(2Zq/(n a0))^3(n-l-1)!/(2n((n+l)!))](2Zq/(n a0))^l)

3) What are the units of this constant?

Now we put everything together to create the radial wavefunction:

Rad[n_,l_]:=Nom[n,l]r^l Exp[-Zq*r/(n a0)]Lr[n,l]

Now we plot the radial wavefunction, ((Subscript[R, n])^l)(r). The radial wavefunction does not depend on θ or ϕ. Therefore, if we want to know the probability of finding the particle in a thin shell of radius r, we simply multiply the probability density above by the area of the shell, 4π (r^2). Notice what the extra factors of r do at the origin.

Manipulate[
RadialWFPlot=Plot[Rad[n,l],{r,0,4n^2}];
RadialProbDensePlot=Plot[Rad[n,l]^2,{r,0,4n^2}];
RadialProbDensePlot=TwoAxisPlot[{Rad[n,l]^2,r^2},{r,0,4n^2}];
RadRProbDensPlot=Plot[r^2Rad[n,l]^2,{r,0,4n^2}];
RadialWFLabel1="The normalized radial";
RadialWFLabel2="wavefunction,"StringForm["((Subscript[R, ``])^(``))(r)",n,l];
RadialProbDensLabel1= "Blue:"StringForm["|((Subscript[R, ``])^(``))(r)\!((|)^2)",n,l];
RadialProbDensLabel2="Purple: (r^2)(r)";
RadRProbDensLabel1="Probability of finding the particle in";
RadRProbDensLabel2="a thin (thickness dr) shell of radius\!\(TraditionalForm\`\(\(\\ \)\(r\)\)\)";
Grid[{{Grid[{{RadialWFLabel1},{RadialWFLabel2},{RadialWFPlot},{}}],
Grid[{{RadialProbDensLabel1},{RadialProbDensLabel2},{RadialProbDensePlot},{}}],
Grid[{{RadRProbDensLabel1},{RadRProbDensLabel2},{RadRProbDensPlot},{}}]}}],
{n,1,10,1},{l,0,n-1,1},TrackedSymbols:>{n,l}]

4) Describe how n and l affect the left plot above.

5) Explain how the right plot arises from the interaction between the curves in the center plot. Note that the curves on the center plot have different vertical axes.

by Corinne Manogue, Kerry Browne, Mike Vignal, and Ian Founds
Copyright 2010 Corinne Manogue