Spherical Harmonics

SetOptions[ParametricPlot3D,PlotPoints -> 50,ColorFunction->Function[{x,y,z,θ,ϕ,r},Hue[0.67(1-Ylmsq[θ,ϕ]/maxx)]],ColorFunctionScaling->False,Boxed->True,Mesh->False,ImageSize->Medium,Ticks->{{0,π/2,π,3π/2,2π},{0,π/2,π},{0}},AxesLabel->{ϕ,Framed["θ",FrameStyle->None,FrameMargins->10],z},ViewPoint->{3π/4,-π,2},BaseStyle->{FontSize->16}];
SetOptions[ParametricPlot,ImageSize->Medium,
ColorFunction->Function[{x,y,z,θ,ϕ,r},Hue[0.67(1-Ylmsq[θ,ϕ]/maxx)]],Mesh->False,Axes->True,AxesOrigin->{0,0},AxesLabel->{ϕ,θ},Ticks->{{{0,0,{0,0.02}},{π/2,π/2,{0,0.02}},{π,π,{0,0.02}},{3*π/2,3*π/2,{0,0.02}},{2*π,2*π,{0,0.02}}},{{0,π,{0,0.02}},{π/2,π/2,{0,0.02}},{π,0,{0,0.02}}}},Frame->False,ColorFunctionScaling->False,BoundaryStyle->None,ImageSize->350,BaseStyle->{FontSize->16}];
SetOptions[Grid,Spacings->2];
SetOptions[SphericalPlot3D,PlotRange->All,ViewPoint->{2.6, 0, 1.4},Axes->False,Boxed->False,Mesh->{30,10},ImageSize->Medium,ColorFunction->Function[{x,y,z,θ,ϕ,r},Hue[0.67(1-Ylmsq[θ,ϕ]/maxx)]]];
SetOptions[Manipulator,Appearance->"Labeled",BaseStyle->{FontSize->20}];
SetOptions[Manipulate,BaseStyle->{FontSize->20}];
Clear[l,m,θ,ϕ];

In this worksheet, you will examine the graphs of the spherical harmonics ((Subscript[Y, l])^m)(θ,ϕ).  Since the spherical harmonics are complex functions of the angular coordinates, it is not possible to plot  ((Subscript[Y, l])^m)(θ,ϕ).  Instead, we will plot the square of the norm, |((Subscript[Y, l])^m)(θ,ϕ)((|)^2), as a function of the angular coordinates.  The square of the norm gives the probability density in quantum mechanics.  NOTE: By looking only at the square of the norm, we are throwing away information about the phase.  We will explore the physical importance of the phase in a subsequent worksheet.

Plot the magnitude and the real and imaginary parts of some spherical harmonics, in color. In all three representations, red is max and blue is min for the magnitude of the sherical harmonic.

Y[l_,m_,θ_,ϕ_]:=SphericalHarmonicY[l,m,θ,ϕ]
Manipulate[
Ylmsq[θ_,ϕ_]=FullSimplify[ComplexExpand[Conjugate[Y[l,m,θ,ϕ]]*Y[l,m,θ,ϕ]]];
maxx=Max[Table[Abs[Ylmsq[θ,ϕ]],{θ,0,π,π/20},{ϕ,0,2π,π/20}]];
Yrect=ParametricPlot3D[{ϕ,θ,Abs[3Y[l,m,θ,ϕ]]^2},{θ,0,π},{ϕ,0,2*π}];
Yreal=ParametricPlot3D[{ϕ,θ,Re[1.5Y[l,m,θ,ϕ]]},{θ,0,π},{ϕ,0,2*π}];
Yim=ParametricPlot3D[{ϕ,θ,Im[1.5Y[l,m,θ,ϕ]]},{θ,0,π},{ϕ,0,2*π}];
YlmLabel=StringForm["((Subscript[Y, ``])^(``))(θ,ϕ)=",l,m][Y[l,m,θ,ϕ]];
YlmsqLabel1=StringForm["|((Subscript[Y, ``])^(``))(θ,ϕ)((|)^2)=",l,m][Ylmsq[θ,ϕ]];
YlmsqLabel2=StringForm["|((Subscript[Y, ``])^(``))(θ,ϕ)((|)^2)",l,m];
YlmReLabel=StringForm["Re[((Subscript[Y, ``])^(``))(θ,ϕ)]",l,m];
YlmImLabel=StringForm["Im[((Subscript[Y, ``])^(``))(θ,ϕ)]",l,m];
Off[N::meprec];
Grid[{{YlmLabel},{},{YlmsqLabel1},{},{"Magnitude:"YlmsqLabel2,"Real Part:"YlmReLabel,"Imaginary Part:"YlmImLabel},{Yrect,Yreal,Yim}}],
{l,0,3,1},{{m,0},-l,l,1},TrackedSymbols:>{l,m}]

1a) Describe how changing l affects the plots.

1b) Describe how changing m affects the plots.

2) What is the ϕ dependence of the square of the norm of a spherical harmonic? What is the significance of this?

And now, we plot several representations of the probability densities, |((Subscript[Y, l])^m)(θ,ϕ)((|)^2), of various spherical hamronics. Some of these plots look like electron orbitals, but these are not electron orbitals. These are representations of 2 spatial dimensions, not 3; radial dependence is not considered here. You should think of spherical harmonics as eigenstates on a sphere.  Note that these representations are not to scale relative to each other; adding the third and fourth representations gets you the fifth representation, but the fifth representation’s size has been downscaled.

Manipulate[
Ylmsq[θ_,ϕ_]=FullSimplify[ComplexExpand[Conjugate[Y[l,m,θ,ϕ]]*Y[l,m,θ,ϕ]]];
maxx=Max[Table[Abs[Ylmsq[θ,ϕ]],{θ,0,π,π/20},{ϕ,0,2π,π/20}]];
Yrect=ParametricPlot3D[{ϕ,θ,Abs[2.5Y[l,m,θ,ϕ]]^2},{θ,0,π},{ϕ,0,2*π}];
Yflat=ParametricPlot[{ϕ,θ},{ϕ,0,2*π},{θ,0,π}];
Ysph1=SphericalPlot3D[1,{θ,0,π},{ϕ,0,2*π},ColorFunction->Function[{x,y,z,θ,ϕ,r},Hue[0.67(1-Ylmsq[θ*Pi,ϕ]/maxx)]]];
Ysph2=SphericalPlot3D[Ylmsq[θ,ϕ],{θ,0,π},{ϕ,0,2*π},ColorFunction->Function[{x,y,z,θ,ϕ,r},Hue[0.67(1-Ylmsq[θ*Pi,ϕ]/maxx)]]];
Ysph3=SphericalPlot3D[1+Ylmsq[θ,ϕ],{θ,0,π},{ϕ,0,2*π},ColorFunction->Function[{x,y,z,θ,ϕ,r},Hue[0.67(1-Ylmsq[θ*Pi,ϕ]/maxx)]]];
YrectLabel="Probability density";
YflatLabel="Flat projection";
Ysph1Label="On a sphere";
Ysph2Label="3D Probability density";
YlmLabel=StringForm["((Subscript[Y, ``])^(``))(θ,ϕ)=",l,m][Y[l,m,θ,ϕ]];
YlmsqLabel=StringForm["|((Subscript[Y, ``])^(``))(θ,ϕ)((|)^2)=",l,m][Ylmsq[θ,ϕ]];
Grid[{{Grid[{{YlmLabel},{},{YlmsqLabel},{}}]},{YrectLabel,YflatLabel,Ysph1Label,Ysph2Label,""},{Yrect,Yflat,Ysph1,Grid[{{Ysph2,Ysph3}}]}}],{{l,0},0,3,1},{{m,0},-l,l,1},TrackedSymbols:>{l,m}]

3) Describe any patterns that seem to depend on l an m.

4) What are the advantages and disadvantages of each of the above representations? Which representation(s) do you prefer?