ORBITS

SetOptions[Plot,BaseStyle->{FontFamily->"Arial",FontSize->16},PlotStyle->{{Black,AbsoluteThickness[1.5]}},AxesLabel-> {"r","Energy"},AxesStyle->Directive[FontFamily->"Arial",FontSize->16,Black,AbsoluteThickness[0.5],Arrowheads[0.04]],TicksStyle->{{Black,AbsoluteThickness[0.5]},{Black,AbsoluteThickness[0.5]}},PlotRange->{-vmax,vmax/2}, 
PlotStyle->{Magenta,Thick},
AspectRatio->1,
ImageSize->500];
SetOptions[ParametricPlot,BaseStyle->{FontFamily->"Arial",FontSize->16},PlotStyle->{{Black,AbsoluteThickness[1.5]}},AxesLabel-> {"x","y"},AxesStyle->Directive[FontFamily->"Arial",FontSize->16,Black,AbsoluteThickness[0.5],Arrowheads[0.04]],TicksStyle->{{Black,AbsoluteThickness[0.5]},{Black,AbsoluteThickness[0.5]}},
PlotRange->All,
PlotStyle->{Thick,Blue},
ImageSize->500];
SetOptions[Manipulate,SaveDefinitions->True,BaseStyle->{FontSize->16}];
SetOptions[Manipulator,Appearance->{"Labeled"},BaseStyle->{FontSize->16}];
$Messages={};

In this worksheet you will evaluate the orbits resulting from different values of the parameters:
•   E, the total energy
•   ℓ, the magnitude of the angular momentum

First, we define the effective potential for reduced mass μ=1 and potential scaling constant k=1:

Veff[r_,L_]:=-1/r+L^2/(2*r^2)

Next, we find and plot a numerical solution of the differential equations (see Taylor p. 300):

(((d^2)r(t))/(dt^2))=((-1)/((((r(t))^2)))) +((ℓ^2)/((((r(t))^3))))     and     ((dϕ(t))/dt)= (ℓ/((((r(t))^2)))),
with the initial conditions     r(0)=(((Sqrt[1+2(ℓ^2)E])-1)/(2E)),     ((dr(0))/dt) = 0     and     ϕ(0) = 0.

soln[Energy_?NumericQ,L_?NumericQ]:=NDSolve[
{r''[t]==-1/(((r[t])^2))+(L^2)/(((r[t])^3)),ϕ'[t]==L/(((r[t])^2)),r[0]==(Sqrt[1+2*(L^2)*Energy]-1)/(2*Energy),r'[0]==0,ϕ[0]==0},{r,ϕ},{t,0,25}]

Manipulate[a=-1/2/Energy;τ=2*π*Sqrt[(a^3)];vmax=Abs[1.1*(1/2/(L^2))];eps=Sqrt[1+Energy*2*(L^2)];rmin=(L^2)/(1+eps);rmax=(L^2)/(1-eps);
g1=ParametricPlot[Evaluate[{r[t]*Cos[ϕ[t]],r[t]*Sin[ϕ[t]]}/.soln[Energy,L][[1]]],{t,0,τ},Epilog->{Orange,Disk[{0,0},a/10],Red,Disk[Evaluate[{r[x]*Cos[ϕ[x]],r[x]*Sin[ϕ[x]]}/.soln[Energy,L][[1]]],a/15]}];g2=Plot[Veff[r,L],{r,0,rmax*1.3},Epilog->{Red,Disk[{r[x]/.soln[Energy,L][[1]],Energy},{1.3*rmax/30,1.5*vmax/30}],Black,Green,Thick,Line[{{rmin,Energy},{rmax,Energy}}]}];
Grid[{{g1,g2}}],{{Energy,-0.4,Energy},-2,-0.2},{{L,0.8,ℓ},0.5,1.58113},{{x,0,t},0,25,AnimationRate->1,Animator,AnimationRepetitions->1,AnimationRunning->False}]

1) How does each parameter (Energy and ℓ) affect the plots?

2) Can the orbit ever be a circle? Parabola? Hyperbola? Explain.

3) When is the particle’s kinetic energy at a maximum and when is it at a minimum? Potential energy? Effective potential?

by Corinne Manogue, Kerry Browne, Jason Janesky, Mike Vignal, and Ian Founds
Copyright 2010 Corinne Manogue